Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Section 1 - Función de muerte general
[--------------------------------------------------
Debería cambiarse de PNJ según los
que queden disponibles y dar
un texto explicatorio adecuado.
--------------------------------------------------]
[ Morirse de hambre ]
To morir en cualquier parte:
if the location is in Cuevas:
muerte en las cuevas;
otherwise:
morir en el pantano.
[ Te aplastan ]
To ser aplastado por (pnj - a patroller):
say "Realmente cabreado [el portador] te arroja al suelo.";
bnw;
say "Tendrás que encontrar otro portad...";
bnw;
say "Oh, no, pero... ¿qué está haciendo?";
bnw;
say "Te pisa, te pisa, te pisa... ¡con violencia!";
bnw;
say "¡Quiere acabar contigo!";
bnw;
say "Y realmente lo termina logrando.";
bnw;
say "Primero es una pequeña grieta en tu ojo esmeraldino, luego un corte completo de la gema, un corte por la que se escapa tu alma de dragón. Un alma probablemente condenada para siempre por su inutilidad y por dejarse matar por seres inferiores.";
end the game saying "FIN".
[ Marca para poner los nombres de los orcos ]
OrcosConocidos is a number that varies. OrcosConocidos is 0.
[ Rutina general en caso de muerte en el pantano ]
To morir en el pantano:
say line break;
[escogemos siempre el más próximo]
let nj be jugador mas proximo;
[say "[nj].";]
if nj is the player:
[Para siempre en el pantano]
fracasar la aventura;
otherwise:
poner cadaver;
[Es el nuevo portador]
[Ponerle el anillo]
now the anillo is worn by nj;
[Reiniciar hambre y sed]
now hambre del jugador is 0;
now sed del jugador is 0;
[Detenerlo]
deactivate nj;
[Ponerlo en dominado]
now nj is dominado;
[Hacer que sea el jugador]
let aj be the player;
now aj is muerto;
contar muerte de aj y encuentro con nj;
move nj to location;
change the player to nj;
[say "[the location].";]
[mover el antiguo jugador fuera de juego]
move aj to NoLugar;
[reinicio de los orcos]
reinicia a los orcos;
[the lobo ya no te reconoce]
now lobo is not contentado.
To cambiar de portador orco:
repeat with pos running through the orco in location:
if pos is not the player:
say "El brillo de tu ojo llama la atención [del pos].";
bnw;
say "La avaricia llena su cara, olvidando todo lo demás, y de inmediato da un empujón a [el portador], haciéndolo caer al suelo.";
bnw;
say "Sin darle oportunidad a recuperarse le quita el anillo de su mano.";
bnw;
say "Ingenuo. Una vez en su mano tomas el control de su mente con gran facilidad.";
if the location is not Pantano19:
bnw;
say "El otro orco, bastante confuso huye entre el follaje.";
now the anillo is carried by pos;
now the player is antiguo poseso;
change the player to pos;
reinicia a los orcos;
if there is a orco (called nohuido) which is not the player in the location:
if nohuido is not the player:
try silently nohuido going south;
break.
[ La parte no descriptiva de matar a un PNJ]
To matar al pnj (pnj - a patroller):
if pnj is not the player:
now pnj is muerto;
if pnj is a posible jugador:
poner cadaver de pnj;
move pnj to NoLugar;
if pnj is an orco:
reinicia a los orcos;
otherwise if pnj is deavork:
now all of the things in estomago del deavork are in the location of deavork;
move deavork_muerto to the location of deavork;
move deavork to Pantano28;
if the location is Pantano28:
say "Un deavork sale de las cuevas.";
otherwise if pnj is lobo:
move lobo_muerto to the location of lobo;
move lobo to NoLugar;
deactivate lobo;
otherwise:
say "QQQ! Fallo se ha intentado 'matar' al jugador usando 'matar al pnj'".
[ Poner el cadaver de un pnj ]
To poner cadaver de (pnj - a posible jugador):
move el cadaver of pnj to the location of pnj;
now all of the things carried by pnj are in the location of el cadaver of pnj.
[ Crear un cadaver adecuado ]
To poner cadaver:
[the cadaver físicamente al lugar]
move el cadaver of the player to the location;
[ahora dejar todo]
now all of the things carried are in the location;
now all of the things worn are in the location.
[ Reiniciar los orcos de forma adecuada ]
To reinicia a los orcos:
[Primero el asunto de los nombres, una vez que el jugador pasa a ser orco]
if OrcosConocidos is 0:
if the player is an orco:
poner nombre propio a orcos;
now OrcosConocidos is 1;
repeat with pj running through orco:
if pj is not in the location or the player is an orco:
deactivate pj;
[ Descartamos los ya muertos y los que sean el jugador ]
if the player is not pj and pj is not in NoLugar:
[ En cualquier caso lo movemos al campamento, si no están visibles ]
if pj is not in the location:
move pj to Pantano19;
if pj is in Pantano19 and the player is an orco:
now pj is esperando;
if pj is zhur and the player is not zhur:
[ Si zhur está vivo siempre estará patrullando ]
now zhur is patrullando;
now zhur is aimless;
activate zhur;
otherwise if pj is yerk:
[ Sólo si zhur está muerto patrulla ]
if zhur is in NoLugar or the player is zhur:
now yerk is patrullando;
now yerk is aimless;
activate yerk;
otherwise if pj is berg:
[ Sólo si zhur y yerk están muertos patrullará ]
if (zhur is in NoLugar or the player is zhur) and (yerk is in NoLugar or the player is yerk):
now berg is patrullando;
now berg is aimless;
activate berg.
To poner nombre propio a orcos:
now the printed name of zhur is "Zhur";
now zhur is proper-named;
now the printed name of berg is "Berg";
now berg is proper-named;
now the printed name of yerk is "Yerk";
now yerk is proper-named;
now the printed name of zhur_muerto is "cadáver de Zhur";
change the indefinite article of zhur_muerto to "el";
now the printed name of berg_muerto is "cadáver de Berg";
change the indefinite article of berg_muerto to "el";
now the printed name of yerk_muerto is "cadáver de Yerk";
change the indefinite article of yerk_muerto to "el";
bnw;
say "Una de las cosas que has podido aprender de este portador son los nombres de los orcos destinados por aquí: Zhur, Berg, Yerk... apestosos nombres de orco.";
bnw;
say "No aprendes su lengua, claro. Puedes haber caído muy bajo pero no 'tan bajo'.".
[DECORACIÓN DE TEXTOS]
[Rutina general que cuenta qué pasa, tras la muerte de un jugador hasta que aparece el otro]
To contar muerte de (aj - a posible jugador) y encuentro con (nj - a posible jugador):
[say "[aj] --> [nj]";
say line break;]
say "Tu portador yace muerto.";
bnw;
[Despedida emotiva de Nuhur]
if aj is nuhur:
recordar a Nuhur;
[Si el nuevo está ahí mismo no hay problema]
if the location of nj is the location of el cadaver of aj:
tener un poco de angustia al pasar de aj a nj;
otherwise:
[say "ouch!";]
tener un mucho de angustia al pasar de aj a nj.
To recordar a Nuhur:
say "Desde que Nuhur te tuvo en su palma por primera vez, sentiste una especie de aprecio por este patético humano. Supones que se trata de un sentimiento parecido al que tienen los humanos por sus mascotas, sus perros de caza o sus aves de cetrería.";
bnw;
say "Te ha servido bien. A pesar de sus evidentes limitaciones y sus miedos, sin él no hubieses podido salir nunca de aquel lamentable castillo perdido en las tierras bajas.";
bnw;
say "Sin él no hubieses llegado hasta el pantano apestoso, a la visión de la fortaleza de Sady Omú.";
bnw;
say "¿Podrás encontrar un portador igual de útil? Lo dudas mucho.";
bnw.
To tener un poco de angustia al pasar de (aj - a posible jugador) a (nj - a posible jugador):
say "[one of]'¿Y ahora qué?', es lo primero que piensas.[or]'Aquí estamos de nuevo', piensas, 'a solas'.[or]Piensas que de nuevo te ves sin un portador.[at random]";
bnw;
say "Después te asaltan recuerdos de [one of]verte devorado por criaturas inferiores, rodeado de detritus, [or]enterrado, perdido en el fondo de un zurrón[at random]...";
bnw;
say "Por un momento te asalta la angustiosa idea de verte abandonado para siempre en el pantano. Una anillo de oro macizo puede durar miles de años. ¿Te espera una eternidad de esperar?";
bnw;
say "Pero entonces ves cómo los ojos [del nj] se posan en ti y [if nj is a orco]te arranca descuidadamente de entre los dedos de [el portador].[otherwise]con eso basta para que contactes con su simple mente.[end if] El resto es fácil, un poco de exploración de una mente simple y luego la dominación completa.".
To tener un mucho de angustia al pasar de (aj - a posible jugador) a (nj - a posible jugador):
say "[one of]Y aquí nos encontramos. Perdidos en mitad de un apestoso pantano.[or]¡Otra vez sin un portador![at random]";
bnw;
say "No puedes dejar de pensar que pronto lloverá de nuevo, que todo se inundará, que este cuerpo, el de tu portador, se hundirá entre los fangos. Que te acabrá arrastrando a un foso de arenas movedizas donde permanercerás para siempre.";
bnw;
say "¡Cualquier cosa es mejor que ese destino! Así que aprovechas cualquier oportunidad, el más miserable animal, el más ridículo, el más minúsculo, e intentas atraerlo... sin suerte...";
bnw;
say "Hasta que finalmente ves surgir de entre la frondosa vegetación [al nj]. [if nj is a orco]Sus ojos avariciosos le delatan, te coge, se alegra. No tiene ni idea de lo que le espera.[otherwise]Te alegras de tu enorme suerte, te basta con brillar un poco y que el simio te observe para contactar con su mente.[end if]";
bnw;
say "El resto es fácil, un poco de exploración de una mente simple y luego la dominación completa.".
To fracasar la aventura:
say "'¡No!', es el grito desesperado que te asalta al sentir que tu portador está muerto.";
bnw;
say "Sabes, en tu fuero interno, que no queda probablemente nadie que pueda servirte de portador.";
bnw;
say "¡No! ¡No, no! ¡¡No!!";
bnw;
say "Pero sabes que es verdad. La amarga verdad.";
bnw;
say "Los días pasan mientras intentas desesperadamente que cualquier minúscula alimaña te lleve, sin suerte. Las semanas se acumulan mientras ves como, poco a poco, los restos de tu último portador son devorados por las alimañas del pantano, sin que ninguna te devore a ti, o simplemente se descomponen.";
bnw;
say "Lentamente te hundes con sus restos óseos en el pantano, y finalmente te rodea la absoluta oscuridad.";
bnw;
say "La más temible ceguera. Para siempre.";
bnw;
say "¿O tal vez no?...";
end the game saying "FIN".
To muerte en las cuevas:
say "Estas cuevas son solitarias.";
bnw;
say "Demasiado solitarias.";
bnw;
say "De hecho aquí te quedas abandonado sin que nada ni nadie llegue a encontrarte.";
bnw;
say "En la oscuridad.";
bnw;
say "La más temible ceguera. Para siempre.";
bnw;
say "¿O tal vez no?...";
end the game saying "FIN".
[HISTORIA: transición general]
[Table of transicion general
frase
"Tu portador yace muerto."
"La espera se hace interminable, mientras ruegas aterrorizado que esto no sea el final, que tu destino no sea hundirte para siempre en las fétidas aguas del Hapawa."]